Fluke 87IV please whisper in my IR :P

[frenky]

//I'm posting this here because someone might find it useful. And it doesn't fit into repair section because nothing was broken..

So I fixed my new/old Fluke IV and it's working great: https://www.eevblog.com/forum/repair/fluke-87-iv-repair-log/

I wanted to use IR-USB feature of Fluke IV to send data to PC. After some googling I found cables which are crazy expensive... About 60$-80$ + shipping.
So I started to look for alternatives and found this schematics:


http://www.itsonlyaudio.com/measurement/fluke-123-opto-isolated-cable/

Well that looks easy. I had most of components at home and put together this:



And here are serial commands:
http://www.pewa.de/DATENBLATT/DBL_FL_FL187-9-89IV_BEFEHLSSATZ_ENGLISCH.PDF

So I opened RealTerm and sent ID<CR> trough it and .... nothing. I should get back something like: "FLUKE 87,V0.39,123456789"  but no...

I then tested if my module works by putting spoon in front of it. It worked. All commands were now echoed back to RealTem.

So why was not my dmm responding...?

[frenky]

So my next thought was there must be something wrong with the schematics because it was too easy.

And then I found this one:

http://kimboricha.blogspot.si/2013/12/build-usb-to-fluke-189-irinfrared.html

This time I did not bother soldering it:


I tested it again with FlukeIV and nothing. DMM just would not answer to any of my requests...

Now that I had two modules I tried if they can talk to each other and yes I could send data from one module to another trough IR with no problem...

[frenky]

It was time for some investigation...

I looked at IR diodes on pcbs of similar models online. 189 is a successor to 89IV and model 187 is a successor to 87IV.

189: More photos: http://mrmodemhead.com/blog/gallery/fluke-189-clean-up/


187: More photos: https://www.eevblog.com/forum/testgear/fluke-187/msg536864/#msg536864


89IV:


And my 87IV:


Hmm....

[frenky]

So the IR module does look a lot different in old models.
HPL845 did not return anything so I started to look for similar IR modules.

Based on looks and number of pins and power and ground lines I have found HSDL-3201 as a peffect match:
http://media.digikey.com/pdf/Data%20Sheets/Lite-On%20PDFs/HSDL-3201.pdf

[frenky]

So I studied the datasheet of HSDL-3201 and found out this interesting parts:
"Output is a low pulse for 2.4 µs when a light pulse is seen."
and
" Logic high turns the LED on. If held high longer than ~ 20 µs, the LED is turned off. "

So this module can't work with just regular SIR (Serial to Infrared) because at 9600 baud rate bits are 105us long and if transmitter is only outputting 20us long pulses serial2usb ic won't understand "serial" data that is getting on RX.

So I learned that this HSDL-3201 is used for IrDA protocol which is quite different from serial:



Veri nice article about IrDA: http://www.eix.co.uk/Articles/IrDA/Welcome.htm

[frenky]

After some investigation into IrDA protocol I concluded that I need IrDA encoder/decoder.

So I ordered a few MCP2140A which is made for 9600 baudrate and does not need external clock.
http://si.farnell.com/microchip/mcp2140a-i-p/controller-irda-9600-baud-pdip18/dp/1439520

While waiting for it to arrive I manually encoded DS<CR> and ID<CR> commands into raw pulses (in Inkscape  ):

[serggio]

---
Understand... you describing your research in multiple messages, instead do it in one..
I'll remove my ones in this thread above

[frenky]

So in red are 20us pulses that need to be sent to dmm. Well I sure did not want to wait for decoder to arrive so I hacked together some code for arduino.
The code sent out raw pulses of DS<CR> which resets DMM. It does this every 5sec.

I've set dmm to DC V pressed the AVG button and pointed IR to ARduino IR. Sure enough a few seconds later DMM reseted from AVG to basic mode.

VICTORY! 

Then I wanted to go furter. Can I use arduino as a decoder too?
Looking at this decoding image I noticed that all I have to do is set up a trigger on falling edge that will output 105us pulse on some pin and connect that pin to RX of USB2Serial module.

Arduino mess:


And tadaaa. It works! 




Code (please don't judge me, I just wanted it to work):

Code: [Select]

#include "DigitalIO.h"
const uint8_t PIN = 5;
const uint8_t PINTX = 9;
const byte interruptPin = 3;

int bitsD[10] = {0,0,0,1,0,0,0,1,0,1};
int bitsS[10] = {0,1,1,0,0,1,0,1,0,1};
int bitsI[10] = {0,1,0,0,1,0,0,1,0,1};//0100 1001
int bitsCR[10] = {0,1,0,1,1,0,0,0,0,1};



void setup() {
  fastPinMode(PIN, OUTPUT);
  fastPinMode(PINTX, OUTPUT);
  pinMode(interruptPin, INPUT_PULLUP);
  attachInterrupt(digitalPinToInterrupt(interruptPin), sendTX, FALLING);
}

void loop() {
  fastDigitalWrite(PIN, LOW);
 
  int i;
  for (i = 0; i < 10; i++) {
    if (bitsI[i]==0) { zero(); }
    else { one(); }
  }
  /*for (i = 0; i < 10; i++) {
    if (bitsS[i]==0) { zero(); }
    else { one(); }
  }*/
  for (i = 0; i < 10; i++) {
    if (bitsD[i]==0) { zero(); }
    else { one(); }
  }
  for (i = 0; i < 10; i++) {
    if (bitsCR[i]==0) { zero(); }
    else { one(); }
  }
 
  delay(5000);
}

void one(){
  delayMicroseconds(105);
}
void zero() {
  delayMicroseconds(46);
  fastDigitalToggle(PIN);
  delayMicroseconds(20);
  fastDigitalToggle(PIN);
  delayMicroseconds(39);
}
void sendTX() {
  fastDigitalWrite(PINTX, LOW);
  delayMicroseconds(105);
  fastDigitalToggle(PINTX);
}
 

[retiredcaps]

Thanks for documenting and sharing. 

[coromonadalix]

Thanks +1

[frenky]

Tnx for supporting my efforts.
I have now removed the external usb2serial module because I can send out pulses of serial data on pin1 which is tx of arduino.

In the folowing days I'll publish code for complete IrDA encoder/decoder so anybody could use 2$ arduino instead of expensive Fluke cable. The code should work with Fluke Forms...

Sent from my LG-D855 using Tapatalk

[dxl]

I own a Fluke 187 and this sounds very interesting. Thank you for your detailed reports!

[frenky]

My arduino code is almost ready and meanwhile I have found conversion from IrDA to bluetooth:
http://goods.ruten.com.tw/item/show?21649693608363

It also shows that IrDA module in 87IV is actually HSDL-3200: http://www.efo.ru/components/avago/catalog/files/pdf/5989-3019EN.pdf
And IrDA encoder/decoder IC is TIR1000: http://www.ti.com/lit/ds/symlink/tir1000.pdf




Edit:
With this info it would be also easy to convert 87IV and 89IV from IrDA to basic Serial IR as in newer models...
Just remove IrDA encoder IC and put in IR diode and phototransistor as in IR2USB cable...

[frenky]

Software implementation of IrDA encoding/decoding is ready for public eye. 

DSO says it works:


So the schematics is really simple: (RX is connected to pin D2 because there is no hardware interrupt on RX pin)


Readable arduino code:

Code: [Select]

#include "DigitalIO.h"
const uint8_t interruptPinIrRx = 3;
const uint8_t interruptPinRX = 2;
const uint8_t PINIrTx = 7;
const uint8_t PINSerialTX = 1;

void setup() {
  fastPinMode(PINSerialTX, OUTPUT);
  fastDigitalWrite(PINSerialTX, HIGH);
  pinMode(interruptPinIrRx, INPUT_PULLUP);
  attachInterrupt(digitalPinToInterrupt(interruptPinIrRx), sendTX, FALLING);
  fastPinMode(PINIrTx, OUTPUT);
  pinMode(interruptPinRX, INPUT_PULLUP);
  attachInterrupt(digitalPinToInterrupt(interruptPinRX), sendIr, FALLING);
}

void sendTX() {
  fastDigitalWrite(PINSerialTX, LOW);
  delayMicroseconds(105);
  fastDigitalToggle(PINSerialTX);
}

void sendIr() {
  delayMicroseconds(46);
  while (digitalRead(2)==LOW){
    fastDigitalWrite(PINIrTx, HIGH);
    delayMicroseconds(20);
    fastDigitalToggle(PINIrTx);
    delayMicroseconds(85);
  }
}

void loop() {
}
Fast less readable code:

Code: [Select]

const uint8_t PINIrTx = 7;//PD7
const uint8_t PINSerialTX = 1; //PD1
const byte interruptPinIrRx = 3;//PD3 INT1
const byte interruptPinRX = 2; //PD2 INT0

void setup() {
  pinMode(PINSerialTX, OUTPUT);
  pinMode(interruptPinIrRx, INPUT_PULLUP);
  attachInterrupt(1, sendTX, FALLING);
  pinMode(PINIrTx, OUTPUT);
  pinMode(interruptPinRX, INPUT_PULLUP);
  attachInterrupt(0, sendIr, FALLING);
}

void loop() {
  PORTD |= _BV(PD1);
}

void sendTX() {
  PORTD &= ~_BV(PD1); //go LOW on pin 1(TX)
  delayMicroseconds(105);
  PIND = _BV(PD1); //toggle pin 1
}

void sendIr() {
  delayMicroseconds(46);
  while ((PIND & (1<<PD2))==0){ //while interruptPinRX is LOW, output 20us pulses
    PORTD |= _BV(PD7); //go HIGH on pin 7 (IR diode)
    delayMicroseconds(20);
    PIND = _BV(PD7);  // go LOW (toggle pin) on pin 7 (IR diode)
    delayMicroseconds(85);
  }
}

First test with arduino serial monitor:


And a final test with FlukeView Forms:



A guess next is a mini IrDA shield for Arduino Nano. 

[serggio]

Hi,

At what points in your scheme you control signal by oscilloscope? Could you post form of your signal between ground and D3 input?

p.s. solution with additional BT module cool, but would be interesting know, how often that guy change battery in him meter.. 

[frenky]

So on this image:

Yellow is signal at D0(RX) and blue is signal on D7. So the image is showing encoding of serial data like here:


At D3 signal is HIGH most of the time. When photo transistor senses IR light the signal on D3 goes LOW:

[serggio]

Thx,

Yes, It should be High level, because on Rx and Tx lines constant High always when no signal transmission (silent). Phototransistor probably work well for your application, because your solution use only 9,6 Bauds speed. Try to use fast speed photodiode and BC847 transistor for example. This will give you much better rise fronts for short pulses. Best phototransistors have couple-tens uS for rise up, while photodiodes have 5-100 nS

[frenky]

Tnx. 
I have SFH203-FA photo diodes (with 5ns switching time) at home. https://goo.gl/j5ibUA
(I have bought many different IR transmitting diodes, detectors and transistors for this mini project...)

Can't wait to try it out to see the recovery time.

[coromonadalix]

i'll try to implement your idea for a gossen metrahit 28s,   it send data in hex or binary mode ,  i have the rs232 protocol infos
but i'm noob in arduino programming ...

asking 300$ usd for an interface ... if i can find it.

[serggio]

I have SFH203-FA photo diodes (with 5ns switching time) at home. https://goo.gl/j5ibUA
(I have bought many different IR transmitting diodes, detectors and transistors for this mini project...)

Can't wait to try it out to see the recovery time.

It should be are bomb!  Osram photodiodes really cool! While I use 100 ns Vishay's T-1 package's photodiodes (17 uA photocurrent), fronts from them also seems very good even for 115,2K baud rate and maximum available amplitude for this speed.

[frenky]

I have replaced photo-transistor SFH300FA with photo-diode SFH203FA but it did not work. Signal barely dipped when IR light reached photo-diode.
I then tested setup like this:


Image source: http://www.ebay.com/itm/13-pc-INFRARED-IR-eXperimenter-Pack-LEDs-Detectors-/350727119911

An this works great standalone, connected just to oscilloscope. I'll change the code to trigger on the rising edge but it should work...

[serggio]

What reason to have 200 Ohm resistor in this chain? Try to increase 22kOhm to 70 kOhm for better amplitude. Best value for bottom resistor you can always find with oscilloscope particularly for your connection speed.  For 9600 baud 100 K also will work well

[frenky]

Not sure, perhaps for diode protection. But since arduino inputs are in high impedance state I don't think it is needed.

With 5V source and with 200ohm top resistor and 10k on the bottom I got 3.8V signal pulses while pointing TVs remote controller into it.
Which is more than enough for stable triggering.

I'll do some more tests...

[serggio]

No sure, perhaps for diode protection. But since arduino inputs are in high impedance state I don't think it is needed.

With 5V source and with 200ohm top resistor and 10k on the bottom I got 3.8V signal pulses while pointing TVs remote controller into it.
Which is more than enough for stable triggering.

I'll do some more tests...

No, no, no.... 
Photodiodes work connected backward than emitting diodes. Reverse voltage 50V for your diode. No any protection resistor needed till you not reach 50V in chain.
Forget about TV remote control. There emitting diode work with high pulse currents more than 100 mA! You need focusing at emitting light power from your meter, that significant lower! 

[frenky]

Photodiodes work connected backward than emitting diodes. Reverse voltage 50V for your diode.

I know that. My thought was that when photo-diode starts conducting in backwards because of IR light the current from source could damage it if there was no resistor in series...
But this could only happen if you had it connected directly between 5V and ground.
I might also be totally wrong about this...

[AintBigAintClever]

Well I guess this explains why the IR189USB cable I bodged together this evening works with my 189 but results in not so much as a flicker of IR with my 89 IV. At least it didn't cost me anything to build as the bits had already been scavenged

I take it your Arduino code is just for 87 IV and 89 IV and won't work on 18x/28x series?

This has inspired me to finally start dabbling with Arduino. As far as I can see it shouldn't be too difficult to extend the code to use additional pins to select between 8xIV and 18x mode (another interrupt which would switch the main interrupts to point at two different pairs of routines?) and rising/falling trigger mode.

 

[frenky]

Yes it would be easy to add some code to just pass trough all incoming serial data to IR TX and RX leds.
And add a switch of jumper to select desired mode...

[AintBigAintClever]

My Arduino arrived today. After a bit of poking and prodding (and failing to read the mode switch with an interrupt, possibly due to switch bouncing)... it works!

The code below expects an SPDT switch connected to pins D10 (pulled high by the Nano), D11 (wiping contact) and D12 (pulled low). This is used as a mode selector, with the Nano's LED indicating the mode; off for 87/89 IV, on for 187/189 mode (and presumably 287/289 as well). Of course you could do it with the switch connected to Vcc, D11 and Ground, but doing it with D10 and D12 allows a three-pin toggle switch to directly mount to the board.

In 87/89 IV mode it uses Frenky's interrupts. In 187/189 mode it disables the interrupts and uses my quick-and-dirty loop which just keeps reading the Tx and IrTx inputs and copying them to the IrRx and Rx outputs. The two modes can be switched at any time, no need to reset the Arduino.

Code: [Select]

#include "DigitalIO.h"
const uint8_t interruptPinIrRx = 3;
const uint8_t interruptPinRX = 2;
const uint8_t PINIrTx = 7;
const uint8_t PINSerialTX = 1;
const uint8_t ModeSelHigh = 10;
const uint8_t ModeSel = 11;
const uint8_t ModeSelLow = 12;
const uint8_t LED = 13;

void setup() {
  fastPinMode(LED, OUTPUT); //Mode indicator LED
  fastPinMode(ModeSelHigh, OUTPUT); //High side of mode selector switch
  fastDigitalWrite(ModeSelHigh, HIGH); //Keep high
  fastPinMode(ModeSelLow, OUTPUT); //High side of mode selector switch
  fastDigitalWrite(ModeSelLow, LOW); //Keep low
  pinMode(ModeSel, INPUT);
  fastPinMode(PINSerialTX, OUTPUT);
  fastDigitalWrite(PINSerialTX, HIGH);
  pinMode(interruptPinIrRx, INPUT_PULLUP);
  fastPinMode(PINIrTx, OUTPUT);
  pinMode(interruptPinRX, INPUT_PULLUP);
}

void IrDA_RX() { //Receive IrDA from Fluke 8xIV
  fastDigitalWrite(PINSerialTX, LOW);
  delayMicroseconds(105);
  fastDigitalToggle(PINSerialTX);
}

void IrDA_TX() { //Transmit IrDA to Fluke 8xIV
  delayMicroseconds(46);
  while (digitalRead(interruptPinRX)==LOW){
    fastDigitalWrite(PINIrTx, HIGH);
    delayMicroseconds(20);
    fastDigitalToggle(PINIrTx);
    delayMicroseconds(85);
  }
}

void loop() {
  if (digitalRead(ModeSel) == 0)
  { //Switch is off, select 87IV/89IV (IrDA) mode
    attachInterrupt(digitalPinToInterrupt(interruptPinIrRx), IrDA_RX, FALLING);
    attachInterrupt(digitalPinToInterrupt(interruptPinRX), IrDA_TX, FALLING);
    fastDigitalWrite(LED, LOW); //Turn off mode LED
    while (digitalRead(ModeSel) == 0)
    {
    }
  }
  if (digitalRead(ModeSel) == 1)
  { //Switch is on, select 187/189/287/289 (IR passthrough) mode
    detachInterrupt(digitalPinToInterrupt(interruptPinIrRx));
    detachInterrupt(digitalPinToInterrupt(interruptPinRX));
    fastDigitalWrite(LED, HIGH); //Turn on mode LED
    while (digitalRead(ModeSel) == 1)
    {
      fastDigitalWrite(PINSerialTX, digitalRead(interruptPinIrRx));
      fastDigitalWrite(PINIrTx, 1-digitalRead(interruptPinRX));
    }
  }
}
I just need to tidy it up a bit now.

[frenky]

Fantastic! 

[Tim5000]

This is excellent - nice work!
I was looking to buy the cable as I want to update the 289 to v1.16, but I have a few arduino's kicking around so might give this a go, especially as I've got a 87-IV, 189 and 289 so this would be a great all-in-one solution.

Which IR components did you go for in the end please?
Is there a blog page/update schematic to have a look at?

[zeroxorer]

Thanks a lot for such a useful information.

Also, I found that Fluke 286/287 are using faster speed : 115200 Baud, no parity, 8 bits, 1 stop bit

So, phototransistor is no longer acceptable.
It is better to use fast photodiodes.

[masterx81]

Sorry for bring back from the dead...
If i'm not wrong, and if i well understood, i  not really need the arduino. I need only an ir module, a tir1000 and an usb-232 chip?
Thanks!

[masterx81]

Sorry for "invade" this discussion, but seem the only one about the fluke ir interface for older meters using irda protocol.
Trying to made it simple (and not use an arduino to do the ir encoding/decoding), i've bought an old USB-IRDA adapter model MI620 of the winxp era, as per photo.
Inside i've found an PL2303HX (usb to 232), an eeprom(containing customizations for the 2303), and a chip labeled HS153SN (that i think is a custom mcu for encode/decode the irda protocol) .
As was impossible fo find the drivers for windows 10, i've removed the eeprom (that contained the customized VEN/PID), so now it's recognized as a normal PL2303 device, and i've installed the drivers.
But the meter was not seen by the software. So i've attached the logic analyzer, and sending characters with a terminal with no flow control i had the output to the photodiode, but with flukeview sending the 0x73 0x68 0x13 command i not had any output to the photodiode. I think that flukeview try to use some sort of flow control the my setup can't use (maybe because not using the correct drivers for the module). So i've removed the pins of flow control from 2303 to the HS153SN encoder and now i have a good signal to the photodiode (as seen the logic analyzer output). If i put a glass in front of the transceiver i get back the signal so i think that must work. But flukeview still not see the meter.
The photodiode pulses are encoded correctly (1,62us pulses, as per irda standard) but i not get back anything from the meter at the output of the phototransistor. If while flukeview is sending the data, i put an old phone sending irda data, i have correct signal at the output of the receiver, so or the meter is not understanding the irda code, or it simply not answer. My meter is a fluke 87-IV firmware 1.01. Maybe on that firmware the irda port is not enabled, and is only for the 89-IV?

[masterx81]

Done! After few mods got it working.
Removed the eeprom, cut traces to pin 7 of the irda enc/dec chip and connected it to pin 4(vcc) and cut trace of pin 9 and connected to gnd.
Work perfectly!

[jordannedev]

Hi collages.
I also try to make a diy infrared communication cable for my Fluke 87IV multimeter, but I have a little trouble.
Generally, I build my schematic around FT232RL & MCP2120. With the jumpers I set the baud rate to 9600 (pins 9, 8, 10 of MCP2120 are connected to GND).
I’m using TFDU4101 infrared transceiver module. I use as reference the information in this post and the schematic from this blog http://lemmini.de/IrDA%20USB/IrDA%20USB.html.
So my problem is that when I point the board to the meter and turn the meter ON I don’t get any response in FlukeViewForms. The software says that “No meter is found” on the corresponding COM port.
I check in the documentation and I didn’t find additional information about some key combination or something else in order to start transmitting from multimeter side.
Please see my schematic and correct me if I’m wrong or share some experience with this multimeter.

[rauldm]

I have bought a Fluke 87 IV, I like it, I have the IR189USB, but doesn't work with this meter, someone know what is the original cable for this meter?

Regards.

[nikifena]

What about implementing the code to an attiny85?

[BeBuLamar]

I have bought a Fluke 87 IV, I like it, I have the IR189USB, but doesn't work with this meter, someone know what is the original cable for this meter?

Regards.

I wonder if the 87 IV is different from the 187 and 189. I have the 189 and it works with the IR189USB cable as well as the older IR to RS-232.

[rauldm]

Yes, is different, even fluke says ir189usb for 18x and 28x series, what rs 2323 oldcable have You?

[masterx81]

87/89IV encode/decode the data using IrDA protocol, while the 187/189 simply send/receive to/from the ir transceiver the rs232 data, that's why it not work. In 87/89 IV there is a chip (mcu/asic/etc) between usb-232 chip and ir that encode (and decode) the data. If you look my previous posts you see that i've adopted an old cheap usb adapter found on ebay, with a chip that was doing the correct idra encoding/decoding. Studyng the protocol you can also program an mcu that do it, but i've found simpler finding something already working and adapting it to the meter.

[Black Phoenix]

Yes, is different, even fluke says ir189usb for 18x and 28x series, what rs 2323 oldcable have You?

Is not the same with the Fluke 5x-II series of thermometers too? From what I got in old newsgroups - https://sci.electronics.design.narkive.com/qh8BODEw/fluke-54-ii-thermometer-ir-port

https://www.amazon.com/gp/customer-reviews/R23T1IHGHG43CS/

"I highly recommend purchasing the flukeview forms package - you need to make
sure you get the IR receiver designed for the 187 meter and not the 189 meter
(they changed specs in between those two) - the 54 and the 187 use the same
sensor so IF YOU HAVE A 187 FLUKEVIEW FORMS KIT, YOU ARE READY TO GO WITH THE
54 THERMAL METER OUT OF THE BOX."

Gave fluke a call today. Here's the story

- the 5x II series has different IR than the 5x II B series. They are not
compatible. They must use different IR transceiver cables. The B series must
use the USB +IR cable. The older meters must use the serial cables, which
are discontinued. The fancy software comes with the cable itself.

Although they mention on the same post said discrepancy between the 187 and the 189 using different receivers and being compatible with the 87IV.
I suppose the user just said something out of his mouth without knowing what he was saying (going by the testing masterx81 done, and I believe more on him).

I know that the 54IIB uses the normal 187/189/287/289 IR receiver REVII with the plastic adapter that is used in the 187/189, since I saw it working. But the original 54II doesn't work with that.

Are you planning in providing a BOM and schematics/PCB to be redone?

[BeBuLamar]

Yes, is different, even fluke says ir189usb for 18x and 28x series, what rs 2323 oldcable have You?

I can't see any part number. It has the 9 pin female RS-232 at one end rather than the USB A connector. I use this with an USB-RS232 adapter and it works for both the 189 and 289. The cable came with the 189. I also have the IR-USB cable that came with the 289 and it also works with both the 189 and 289.

[rauldm]

Don't worry, the serial cable works with 89 IV true?

[BeBuLamar]

Don't worry, the serial cable works with 89 IV true?

It works with the 189. I don't have the 89 IV that is why the question are they different?

[rauldm]

Because Fluke 87 IV & 89 IV just using IrDA protocol like show in posts above. Early Flukes like 187, 189, 287 and 289, works with serial protocol, I think my IR189USB doesn't work with 87 IV.

[rauldm]

I put the code in my arduino uno, works very fine, I don't need remove the infrared cover, I can configure the meter from PC and synchronize hour.

[dgm_mixtoon]

hello, this mod work on fluke 287?

[evmillan]

Yes, the Fluke 28x series and the Fluke 18x series share the same cable/protocol (with an adapter to fix it to the meter). The Fluke 189 is a rebranded Fluke 87IV with few improvements.